# -*- python -*-

import os
import os.path
import glob

Import('env final_prefix install_prefix libraries i18n')

gtkmmext = env.Copy()
gtkmmext.Merge ([ 
    libraries['sigc'], 
    libraries['pbd'],
    libraries['midi++'],
    libraries['gtk'],
    libraries['gtkmm']
    ])

#
# this defines the version number of libgtkmmext
# 

domain = 'libgtkmmext'

gtkmmext.Append(DOMAIN=domain,MAJOR=7,MINOR=0,MICRO=8)
gtkmmext.Append(CXXFLAGS="-DPACKAGE=\\\"" + domain + "\\\"")
gtkmmext.Append(PACKAGE=domain)
gtkmmext.Append(POTFILE=domain + '.pot')

gtkmmext_files = Split("""
auto_spin.cc
barcontroller.cc
bindable_button.cc
choice.cc
click_box.cc
controller.cc
fastmeter.cc
gdkutils.c
generic_motion_feedback.cc
gtk_ui.cc
gtkutils.c
hexentry.cc
idle_adjustment.cc
motionfeedback.cc
newsavedialog.cc
pix.cc
pixmap_button.cc
pixscroller.cc
popup.cc
popup_selector.cc
prompter.cc
selector.cc
shaped_window.cc
slider_controller.cc
spinner.cc
tearoff.cc
textviewer.cc
utils.cc
version.cc
""")

gtkmmext.VersionBuild(['version.cc','gtkmmext/version.h'], 'SConscript')

gtkmmext.Append(CCFLAGS="-D_REENTRANT")
gtkmmext.Append(CCFLAGS="-DLOCALEDIR=\\\""+final_prefix+"/share/locale\\\"")

libgtkmmext = gtkmmext.StaticLibrary('gtkmmext', gtkmmext_files)

Default(libgtkmmext)

if env['NLS']:
    i18n (gtkmmext, gtkmmext_files, env)

env.Alias('tarball', env.Distribute (env['DISTTREE'],
                                     [ 'SConscript', 'i18n.h', 'gettext.h'] +
                                     gtkmmext_files +
                                     glob.glob('po/*.po') +
                                     glob.glob('gtkmmext/*.h')))
